〜 ファイル 〜
ＩＮＩファイルのデータを削除 (要KERNEL32.DLL) 
「*.ini」ファイル内情報を削除するサンプルです。
ＩＮＩファイルとはＷｉｎｄｏｗｓフォルダに入っているwin.iniファイル等と同じものであり、
拡張子こそ通常のテキストファイル「*.txt」とは違いますが中身はそれと同じですので、
書式に沿って、ＩＮＩファイルから削除対象以外をbsave命令やnotesave命令で書き換えてもよいですが、
ＷｉｎＡＰＩを用いて設定する場合、設定と同じWritePrivateProfileString関数というものを使用します。
削除も設定もほぼ同じやり方なので、分けてやる必要もないかもしれませんが、
削除だけを考えたときにわかりやすくするため、別途用意しました。
ＡＰＩで指定する際、書き込む値(第３引数)をＮＵＬＬ(=0)にすると指定されたキーを削除し、
キー(第２引数)をＮＵＬＬ(=0)にすると指定されたセクションを削除します。
尚、ＩＮＩの基本書式として、下記のようになっています。


	[セクション１]
	キー１ = データ１
	キー２ = データ２
	キー３ = データ３
	　　：
	　　：
	
	[セクション２]
	キー１ = データ１
	キー２ = データ２
	キー３ = データ３
	　　：
	　　：

setini 設定情報配列
設定情報配列ＩＮＩファイルに設定する情報を文字列型配列で指定する。
各設定要素は、保存ファイル(=0)、セクション(=1)、キー(=2)、値(=3)とする。
尚、設定に失敗したら、statに０が、成功なら１が返る。

delini 削除情報配列
削除情報配列ＩＮＩファイルの削除する情報を文字列型配列で指定する。
各設定要素は、削除ファイル(=0)、セクション(=1)、キー(=2)、値(=3)とする。
尚、セクション自体を削除するなら、キー部を空文字にすること。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

	ll_libload kernel, "kernel32.dll"
	ll_getproc WritePrivateProfileString, "WritePrivateProfileStringA", kernel

#module
#deffunc setini val
	mref info, 56
	mref stt, 64
	ll_getptr info.0 : ll_ret prm.3
	ll_getptr info.1 : ll_ret prm.0
	ll_getptr info.2 : ll_ret prm.1
	ll_getptr info.3 : ll_ret prm.2
	ll_callfunc prm, 4, WritePrivateProfileString@
	ll_ret prm : stt = prm
	return

#deffunc delini val
	mref info, 56
	ll_getptr info.0 : ll_ret prm.3
	ll_getptr info.1 : ll_ret prm.0
	if info.2 = "" : prm.1 = 0, 0 : else : ll_getptr info.2 : ll_ret prm.1 : prm.2 = 0
	ll_callfunc prm, 4, WritePrivateProfileString@
	return
#global

	// ＩＮＩファイル作成
	sdim string, 256, 4
	dummy = 3, 5, 3, 4 // section総数, section1のkey数, section2のkey数, section3のkey数
	fname = curdir + "\\" + "hspbc_tips.ini"
	repeat dummy
		i = cnt + 1, cnt
		repeat dummy.i
			string = fname, "Section" + i.1, "Key" + cnt, "Data" + cnt
			setini string
			if stat = 0 {
				dialog "一時ＩＮＩファイル作成に失敗しました"
				end
			}
			loop
	loop
	// ＩＮＩファイル構成
	pos  10, 10 : mes "セクション"
	pos 100, 10 : combox index.0, 100, "0\n1\n2"
	pos 200, 10 : button "削除", *deleteini
	pos  10, 40 : mes "キー"
	pos 100, 40 : combox index.2, 100, ""
	pos 200, 40 : button "削除", *deleteini
	gosub *change

*main
	wait 5
	if index ! index.1 : gosub *change
	goto *main

*change
	index.1 = index
	keyinfo = ""
	i = index + 1
	repeat dummy.i
		if keyinfo ! "" : keyinfo += "\n"
		keyinfo += "" + cnt
	loop
	objprm 2, keyinfo
	objprm 2, 0
	return

*deleteini
	if stat = 1 {
		dialog "指定したセクションを丸ごと削除しますか？", 2
		string = fname, "Section" + index, ""
		if stat = 6 : delini string
	} else {
		dialog "指定したキーを削除しますか？", 2
		string = fname, "Section" + index, "Key" + index.2
		if stat = 6 : delini string
	}
	goto *main

成功フラグ = setini(保存ファイル, セクション, キー, 値)
成功フラグ設定失敗(=0)か成功(=1)かのフラグ値受取先を指定する。
保存ファイル保存対象ＩＮＩファイルを指定する。
セクションＩＮＩファイルに設定するセクションを指定する。
キーＩＮＩファイルに設定するキーを指定する。
値ＩＮＩファイルに設定する値を指定する。

delini 削除ファイル, セクション, キー
削除ファイル対象ＩＮＩファイルを指定する。
セクションＩＮＩファイルの削除するセクションを指定する。
キーＩＮＩファイルの削除するキーを指定する。セクション自体を削除する場合はキー名を空文字にすること。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

#uselib "kernel32.dll"
#cfunc global WritePrivateProfileString "WritePrivateProfileStringA" sptr, sptr, sptr, sptr

#module
#defcfunc setini str file, str section, str key, str value, local s
	s = section, key, value, file
	return WritePrivateProfileString(s.0, s.1, s.2, s.3)

#deffunc delini str file, str section, str key, local s
	s = section, key, file
	if key = "" {
		dummy = WritePrivateProfileString(s.0, 0, 0, s.2)
	} else {
		dummy = WritePrivateProfileString(s.0, s.1, 0, s.2)
	}
	return
#global

	// ＩＮＩファイル作成
	dummy = 3, 5, 3, 4 // section総数, section1のkey数, section2のkey数, section3のkey数
	fname = dir_cur + "\\" + "hspbc_tips.ini"
	repeat dummy
		i = cnt
		repeat dummy(i + 1)
			if setini(fname, "Section" + i, "Key" + cnt, "Data" + cnt) = 0 {
				dialog "一時ＩＮＩファイル作成に失敗しました"
				end
			}
			loop
	loop
	// ＩＮＩファイル構成
	pos  10, 10 : mes "セクション"
	pos 100, 10 : combox index.0, 100, "0\n1\n2"
	pos 200, 10 : button gosub "削除", *deleteini
	pos  10, 40 : mes "キー"
	pos 100, 40 : combox index.2, 100, ""
	pos 200, 40 : button gosub "削除", *deleteini
	gosub *change

*main
	wait 5
	if index ! index.1 : gosub *change
	goto *main

*change
	index.1 = index
	keyinfo = ""
	repeat dummy(index + 1)
		if keyinfo ! "" : keyinfo += "\n"
		keyinfo += str(cnt)
	loop
	objprm 2, keyinfo
	objprm 2, 0
	return

*deleteini
	if stat = 1 {
		dialog "指定したセクションを丸ごと削除しますか？", 2
		if stat = 6 : delini fname, "Section" + index, ""
	} else {
		dialog "指定したキーを削除しますか？", 2
		if stat = 6 : delini fname, "Section" + index, "Key" + index.2
	}
	return