実行ファイルやＤＬＬに入っているアイコンをＨＳＰウィンドウ内に描画するには、
ＡＰＩ関数ExtractIconで特定のアイコンリソースを抽出しましょう。
ExtractIconのパラメータには「インスタンスハンドル」「ファイルパス」「インデクス」を指定します。
インスタンスハンドルにはＢＭＳＣＲ構造体の要素１４に格納されている値を指定、
ファイルパスはアイコンの格納されたファイルパスを格納した変数ポインタを指定、
インデクスは一番初めを０としたアイコン番号を指定します。
ファイルに幾つアイコンが含まれているかわからない場合はインデクスに−１を指定することで、
格納されているアイコン数を取得することが出来ます。
尚、ＡＰＩ関数ExtractIconはアイコンのハンドル(管理番号)を取得するだけのものであるため、
ウィンドウ内に描画するにはＡＰＩ関数DrawIconまたはDrawIconExを使う必要があります。
また、アイコンが不要になればＡＰＩ関数DestroyIconでハンドルを解放してください。
ココで紹介するＡＰＩ関数DrawIconのパラメータには第１引数から順に
「デバイスコンテキスト」「描画基点Ｘ座標」「描画基点Ｙ座標」「アイコンハンドル」を指定します。
デバイスコンテキストは描画先であるＨＳＰのhdc(ＨＳＰ２はＢＭＳＣＲ構造体要素４の値)を指定、
描画基点ＸＹ座標はウィンドウ左上を(０,０)としたpos同様の座標を指定、
アイコンハンドルにＡＰＩ関数ExtractIconで取得したハンドルを指定します。

ＡＰＩ関数DrawIconは小さいアイコンを取得しても大きいアイコンサイズで取得されてしまうので、
サイズ指定または実際のサイズで描画する場合はコチラで紹介しているDrawIconExを使ってください。
また、ファイルに含まれている複数のアイコンを一度に取得したい場合、
１ファイルに含まれているアイコン数を取得する場合もコチラを参考にしてください。
	

drawicon アイコンパス, インデクス
	アイコンパス		描画対象アイコンファイルのパスを指定する
	インデクス		マルチプルアイコンのインデクスを指定する

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25

	ll_libload user, "user32.dll"
	ll_getproc DestroyIcon, "DestroyIcon", user
	ll_getproc DrawIconAPI, "DrawIcon", user // 関数名に使いたいので末尾にＡＰＩを付けた
	ll_libload shell, "shell32.dll"
	ll_getproc ExtractIcon, "ExtractIconA", shell

#module
#deffunc drawicon str, int
	mref file, 32 : mref no, 1
	mref bmscr, 67
	prm = bmscr.14, 0, no
	ll_getptr file : ll_ret prm.1
	ll_callfunc prm, 3, ExtractIcon@ : ll_ret h
	if h {
		prm = bmscr.4, csrx, csry, h
		ll_callfunc prm, 4, DrawIconAPI@
		ll_callfunc h, 1, DestroyIcon@
		redraw 1 // ＡＰＩから直接描画した場合は画面を更新しなければならない
	}
	return
#global

	dialog "ico", 16, "読み込むアイコン"
	if stat : pos 50, 50 : drawicon refstr // アイコン読込
	stop

drawicon アイコンパス, インデクス
	アイコンパス		描画対象アイコンファイルのパスを指定する
	インデクス		マルチプルアイコンのインデクスを指定する

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20

#uselib "user32.dll"
#func  global DestroyIcon "DestroyIcon" int
#func  global DrawIconAPI "DrawIcon" int, int, int, int // 関数名に使いたいので末尾にＡＰＩを付けた
#uselib "shell32.dll"
#cfunc global ExtractIcon "ExtractIconA" int, str, int

#module
#deffunc drawicon str file, int no
	mref bmscr, 67
	h = ExtractIcon(bmscr.14, file, no)
	if h {
		DrawIconAPI bmscr.4, ginfo_cx, ginfo_cy, h
		DestroyIcon h
		redraw 1 // ＡＰＩから直接描画した場合は画面を更新しなければならない
	}
	return
#global

	dialog "ico", 16, "読み込むアイコン"
	if stat : pos 50, 50 : drawicon refstr // アイコン読込