〜 インプット 〜
マウスの移動可能領域を取得 (要USER32.DLL) 
通常、マウスはディスプレイの端から反対側の端まで自由に移動させることができますが、
一定の領域から外に出られてはマズい場合にコチラのように移動範囲を制限することができます。
移動範囲がディスプレイ全体ではない場合に「どこからどこまでが移動できる領域なのか」を
知らなければならない時はＡＰＩ関数のGetClipCursorで移動可能矩形を知ることができます。
左端・上端・右端・下端座標を格納できる４要素分以上を持った配列変数を渡すことで、
ディスプレイ左上を基点にした各座標を取得出来るので、下記サンプルモジュールの要領で取得してください。
尚、取得と同時に移動範囲を設定するモジュール命令を使用していますが、
この命令にあってはコチラの設定Ｔｉｐｓを参照してください。

mousearea 座標格納配列
座標格納配列左上基点となるＸ・Ｙ座標、右下終点となるＸ・Ｙ座標の受取先となる数値型配列変数を指定する。

mousebind 基点Ｘ座標, 基点Ｙ座標, 終点Ｘ座標, 終点Ｙ座標
基点Ｘ座標移動可能領域左端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。
基点Ｙ座標移動可能領域上端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。
終点Ｘ座標移動可能領域右端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。
終点Ｙ座標移動可能領域下端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

	ll_libload user, "user32.dll"
	ll_getproc ClipCursor, "ClipCursor", user
	ll_getproc GetClipCursor, "GetClipCursor", user

#module
#deffunc mousearea val
	mref area, 48
	mref stt, 64
	ll_getptr area : ll_ret rect
	ll_callfunc rect, 1, GetClipCursor@ : ll_ret prm : stt = prm
	return

#deffunc mousebind int, int, int, int
	mref left, 0 : mref top, 1 : mref right, 2 : mref bottom, 3
	i = left, top, right, bottom
	if i.0 ! 0 | (i.1 ! 0) | (i.2 ! 0) | (i.3 ! 0) {
		ll_getptr i
		ll_ret rect
	} else {
		rect = 0
	}
	ll_callfunc rect, 1, ClipCursor@
	return
#global

	sdim msg, 10, 2
	msg = "制限する", "解除する"
	area = 100, 100, 500, 400
	dim chk, 4
	bgscr 2, dispx, dispy, , 0, 0
	objsize 80, 20
	pos 150, 150 : button msg.0, *binding
	pos 150, 180 : button "終了", *exit
	onexit *exit

*binding
	bflg = 1 - bflg
	objprm 0, msg.bflg
	mousebind bflg * area.0, bflg * area.1, bflg * area.2, bflg * area.3
	mousearea chk
	if stat {
		redraw 0
		color 255, 255, 255 : boxf
		color 200, 100, 200 : boxf chk, chk.1, chk.2, chk.3
		redraw 1
	} else {
		dialog "範囲の取得に失敗しました"
	}
	stop

*exit
	mousebind

mousearea 座標格納配列
座標格納配列左上基点となるＸ・Ｙ座標、右下終点となるＸ・Ｙ座標の受取先となる数値型配列変数を指定する。

mousebind 基点Ｘ座標, 基点Ｙ座標, 終点Ｘ座標, 終点Ｙ座標
基点Ｘ座標移動可能領域左端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。
基点Ｙ座標移動可能領域上端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。
終点Ｘ座標移動可能領域右端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。
終点Ｙ座標移動可能領域下端の座標を指定する。尚、すべてのパラメータを０にすると解除とする。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

#uselib "user32.dll"
#func  global ClipCursor "ClipCursor" int
#func  global GetClipCursor "GetClipCursor" var

#module
#deffunc mousearea array area
	GetClipCursor area
	return

#deffunc mousebind int left, int top, int right, int bottom, local i
	i = left, top, right, bottom
	ClipCursor (i.0 ! 0 | i.1 ! 0 | i.2 ! 0 | i.3 ! 0) * varptr(i)
	return
#global

	msg = "制限する", "解除する"
	area = 100, 100, 500, 400
	dim chk, 4
	bgscr 0, ginfo_dispx, ginfo_dispy, , 0, 0
	objsize 80, 20
	pos 150, 150 : button msg.0, *binding
	pos 150, 180 : button "終了", *exit
	onexit *exit

*binding
	bflg = 1 - bflg
	objprm 0, msg.bflg
	mousebind bflg * area.0, bflg * area.1, bflg * area.2, bflg * area.3
	mousearea chk
	if stat {
		redraw 0
		color 255, 255, 255 : boxf
		color 200, 100, 200 : boxf chk, chk.1, chk.2, chk.3
		redraw 1
	} else {
		dialog "範囲の取得に失敗しました"
	}
	stop

*exit
	mousebind
	end