〜 メディア 〜
時間フォーマットを変更 
デフォルトでは時間の単位が「分：秒：フレーム」であるＭＳＦ形式となっています。
この単位は、現在の位置や曲の長さ等を取得した時、設定する時に使用するもので、
用途によっては異なる単位の方が扱いやすい、ＭＳＦ形式では扱いにくい場合もあることでしょう。
例えば、ＣＤのトラック再生時、ＭＳＦでは再生したいトラックの開始位置を取得しなければなりません。
この単位を「トラック：分：秒：フレーム」であるＴＭＳＦ形式で指定できると操作しやすくなりますね。
今回は、この時間の単位を変更するサンプルを紹介します。
尚、指定できる単位文字列には以下のものが用意されています。



単 位内 容


msミリ秒


millisecondsミリ秒


msf分：秒：フレーム (初期)


tmsfトラック：分：秒：フレーム



下記のサンプルでは、ＭＣＩ共通モジュールを使用して曲再生・停止、トラック数の取得を行っています。
時間フォーマットを変更するmcisettime命令以外についてはコチラとコチラを参照してください。

mciload ファイルパス, 番号
ファイルパス再生するファイルパスを指定する。
尚、"1"ならＡ、"2"ならＢ、"26"ならＺドライブとしたＣＤオーディオ形式でロードする。
番号割り当てるバッファ番号を指定する。
尚、当命令を実行すると、自動的に指定番号が操作対象バッファとなる。

mciplay 開始位置, 終了位置, 繰り返し
開始位置省略可能(省略時は空文字""を指定すること)。再生開始位置を指定する。
尚、指定は数値文字列、現在のフォーマット(初期はＭＳＦ"mm:ss:ff")で行う。
終了位置省略可能(省略時は空文字""を指定すること)。再生終了位置を指定する。
尚、指定は数値文字列、現在のフォーマット(初期はＭＳＦ"mm:ss:ff")で行う。
繰り返し最後まで再生したら自動的に初めから再生する(=1)か否(=0)かを指定する。

mciexit
[パラメータなし]全デバイスを解放するだけの為、パラメータは必要ない。
尚、終了時に自動的に呼び出されるので命令を実行する必要はない。

mcisettime フォーマット
フォーマット時間単位を「ms」「milliseconds」「msf」「tmsf」の中から指定する。

mcitrackmax
[パラメータなし]選択バッファの総トラック数を取得するだけの為、パラメータは必要ない。
尚、取得トラック総数はstatに入る。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

#module
#deffunc mciload str, int
	mref file, 32 : mref no, 1
	cntno = no
	mci "close _" + cntno
	strmid i, file, , 2 : int i
	if i {
		file = "cdaudio!?"
		poke file, 8, i + 64
	}
	mci "open \"" + file + "\" alias _" + cntno
	return

#deffunc mciplay str, str, int
	mref start, 32 : mref finish, 33 : mref re, 2
	if start ! "" : s = " from " + start : else : s = ""
	if finish ! "" : s += " to " + finish
	if re : s += " repeat"
	mci "play _" + cntno + s
	return

#deffunc mciend onexit
	mci "stop all"
	mci "close all"
	return

#deffunc mcisettime str
	mref format, 32
	mci "set _" + cntno + " time format " + format
	return

#deffunc mcitrackmax
	mci "status _" + cntno + " number of tracks"
	return
#global

	repeat 26, 1
		mciload "" + cnt
		mcitrackmax
		drv.1 = stat
		if drv < drv.1 : drv = drv.1 * 100 + cnt // トラック最多ドライブを対象とする
	loop
	if drv.1 > 0 {
		sdim track, drv / 100 * 3
		repeat drv.1, 1
			if track ! "" : track += "\n"
			track += "" + cnt
		loop
		pos 10, 10 : combox index, 100, track
		pos 80, 10 : button "再生", *play
		i = drv \ 100
		mciload "" + i
		mcisettime "tmsf"
	} else {
		dialog "１つ以上のトラックが存在するドライブが見つかりませんでした"
		end
	}
	stop

*play
	i = index + 1
	mciplay "" + i, ""
	stop

mciload ファイルパス, 番号
ファイルパス再生するファイルパスを指定する。
尚、"1"ならＡ、"2"ならＢ、"26"ならＺドライブとしたＣＤオーディオ形式でロードする。
番号割り当てるバッファ番号を指定する。

mciplay 番号, 繰り返し, 再生位置
番号再生するバッファ番号を指定する。
繰り返し最後まで再生したら自動的に初めから再生する(=1)か否(=0)かを指定する。
再生位置ミリ秒単位の再生位置を指定する。

mciexit
[パラメータなし]全デバイスを解放するだけの為、パラメータは必要ない。
尚、終了時に自動的に呼び出されるので命令を実行する必要はない。

mcisettime フォーマット
フォーマット時間単位を「ms」「milliseconds」「msf」「tmsf」の中から指定する。

トラック数 = mcitrackmax()
トラック数取得したトラック総数の受取先を指定する。
[パラメータなし]選択バッファの総トラック数を取得するだけの為、パラメータは必要ない。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

#module
#deffunc mciload str file, int no, local s
	cntno = no
	mci "close _" + cntno
	if int(file) {
		s = "cdaudio!?"
		poke s, 8, int(file) + 64
	} else {
		s = file
	}
	mci "open \"" + s + "\" alias _" + cntno
	return

#deffunc mciplay str start, str finish, int re, local s
	if start ! "" : s = " from " + start : else : s = ""
	if finish ! "" : s += " to " + finish
	if re : s += " repeat"
	mci "play _" + cntno + s
	return

#deffunc mciend onexit
	mci "stop all"
	mci "close all"
	return

#deffunc mcisettime str format
	mci "set _" + cntno + " time format " + format
	return

#defcfunc mcitrackmax
	mci "status _" + cntno + " number of tracks"
	return stat
#global

	repeat 26, 1
		mciload str(cnt)
		drv.1 = mcitrackmax()
		if drv < drv.1 : drv = drv.1 * 100 + cnt	// トラック最多ドライブを対象とする
	loop
	if drv.1 > 0 {
		sdim track, drv / 100 * 3
		repeat drv.1, 1
			if track ! "" : track += "\n"
			track += str(cnt)
		loop
		pos 10, 10 : combox index, 100, track
		pos 80, 10 : button gosub "再生", *play
		mciload str(drv \ 100)
		mcisettime "tmsf"
	} else {
		dialog "１つ以上のトラックが存在するドライブが見つかりませんでした"
		end
	}
	stop

*play
	mciplay str(index + 1), ""
	return