〜 メディア 〜
現在の再生トラック番号を取得 
楽曲の情報を知るためには、まず再生されているトラック番号を知る必要があります。
トラック番号を取得するには「mci "status cdaudio current track"」というように記述しますが、
この記述で正常動作するのは、ディスクドライブが１つ、または先頭(若い方)のＣＤドライブを操作する時で、
仮想ドライブやＤＶＤドライブ等、複数ドライブが並んでいる場合はうまく行かないことがあります。
例えばＸドライブをチェックするには「mci "status cdaudio!X current track"」と記述しましょう。
「！ドライブ名」部分は「！ドライブ名：」や「！ドライブ名：￥￥」としても正常動作します。
サンプルでは、ＭＣＩ共通モジュール仕様に則り、バッファ番号で指定する形を取っています。

mciload ファイルパス, 番号
ファイルパス再生するファイルパスを指定する。
尚、"1"ならＡ、"2"ならＢ、"26"ならＺドライブとしたＣＤオーディオ形式でロードする。
番号割り当てるバッファ番号を指定する。
尚、当命令を実行すると、自動的に指定番号が操作対象バッファとなる。

mciplay 開始位置, 終了位置, 繰り返し
開始位置省略可能(省略時は空文字""を指定すること)。再生開始位置を指定する。
尚、指定は数値文字列、現在のフォーマット(初期はＭＳＦ"mm:ss:ff")で行う。
終了位置省略可能(省略時は空文字""を指定すること)。再生終了位置を指定する。
尚、指定は数値文字列、現在のフォーマット(初期はＭＳＦ"mm:ss:ff")で行う。
繰り返し最後まで再生したら自動的に初めから再生する(=1)か否(=0)かを指定する。

mciexit
[パラメータなし]全デバイスを解放するだけの為、パラメータは必要ない。
尚、終了時に自動的に呼び出されるので命令を実行する必要はない。

mcisettime フォーマット
フォーマット時間単位を「ms」「milliseconds」「msf」「tmsf」の中から指定する。

mcitrackmax
[パラメータなし]選択バッファの総トラック数を取得するだけの為、パラメータは必要ない。
尚、取得トラック総数はstatに入る。

mcitracknow
[パラメータなし]選択バッファの再生トラックを取得するだけの為、パラメータは必要ない。
尚、取得トラックはstatに入る。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

#module
#deffunc mciload str, int
	mref file, 32 : mref no, 1
	cntno = no
	mci "close _" + cntno
	strmid i, file, , 2 : int i
	if i {
		file = "cdaudio!?"
		poke file, 8, i + 64
	}
	mci "open \"" + file + "\" alias _" + cntno
	return

#deffunc mciplay str, str, int
	mref start, 32 : mref finish, 33 : mref re, 2
	if start ! "" : s = " from " + start : else : s = ""
	if finish ! "" : s += " to " + finish
	if re : s += " repeat"
	mci "play _" + cntno + s
	return

#deffunc mciend onexit
	mci "stop all"
	mci "close all"
	return

#deffunc mcisettime str
	mref format, 32
	mci "set _" + cntno + " time format " + format
	return

#deffunc mcitrackmax
	mci "status _" + cntno + " number of tracks"
	return

#deffunc mcitracknow
	mci "status _" + cntno + " current track"
	return
#global

	repeat 26, 1
		mciload "" + cnt
		mcitrackmax
		drv.1 = stat
		if drv < drv.1 : drv = drv.1 * 100 + cnt // トラック最多ドライブを対象とする
	loop
	if drv < 1 {
		dialog "１つ以上のトラックが存在するドライブが見つかりませんでした"
		end
	}
	sdim track, drv / 100 * 3
	repeat drv / 100, 1
		if track ! "" : track += "\n"
		track += "" + cnt
	loop
	pos 10, 10 : combox index, 100, track
	pos 80, 10 : button "回答", *answer
	i = drv \ 100 : str i
	mciload i
	mcisettime "tmsf"
	randomize
	rnd r, drv / 100
	i = r + 1
	mciplay "" + i, ""
	pos 10, 120 : mes "現在再生中のトラックはどれでしょう？"
	stop

*answer
	mcitracknow
	ans = stat, index + 1
	if ans = ans.1 {
		dialog "ご名答！"
		end
	}
	mes "" + ans.1 + "トラックではありません"
	stop

mciload ファイルパス, 番号
ファイルパス再生するファイルパスを指定する。
尚、"1"ならＡ、"2"ならＢ、"26"ならＺドライブとしたＣＤオーディオ形式でロードする。
番号割り当てるバッファ番号を指定する。

mciplay 番号, 繰り返し, 再生位置
番号再生するバッファ番号を指定する。
繰り返し最後まで再生したら自動的に初めから再生する(=1)か否(=0)かを指定する。
再生位置ミリ秒単位の再生位置を指定する。

mciexit
[パラメータなし]全デバイスを解放するだけの為、パラメータは必要ない。
尚、終了時に自動的に呼び出されるので命令を実行する必要はない。

mcisettime フォーマット
フォーマット時間単位を「ms」「milliseconds」「msf」「tmsf」の中から指定する。

トラック数 = mcitrackmax()
トラック数取得したトラック総数の受取先を指定する。
[パラメータなし]選択バッファの総トラック数を取得するだけの為、パラメータは必要ない。

トラック番号 = mcitracknow()
トラック番号取得した再生中のトラック番号の受取先を指定する。
[パラメータなし]選択バッファの再生トラックを取得するだけの為、パラメータは必要ない。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

#module
#deffunc mciload str file, int no, local s
	cntno = no
	mci "close _" + cntno
	if int(file) {
		s = "cdaudio!?"
		poke s, 8, int(file) + 64
	} else {
		s = file
	}
	mci "open \"" + s + "\" alias _" + cntno
	return

#deffunc mciplay str start, str finish, int re, local s
	if start ! "" : s = " from " + start : else : s = ""
	if finish ! "" : s += " to " + finish
	if re : s += " repeat"
	mci "play _" + cntno + s
	return

#deffunc mciend onexit
	mci "stop all"
	mci "close all"
	return

#deffunc mcisettime str format
	mci "set _" + cntno + " time format " + format
	return

#defcfunc mcitrackmax
	mci "status _" + cntno + " number of tracks"
	return stat

#defcfunc mcitracknow
	mci "status _" + cntno + " current track"
	return stat
#global

	repeat 26, 1
		mciload str(cnt)
		drv.1 = mcitrackmax()
		if drv < drv.1 : drv = drv.1 * 100 + cnt // トラック最多ドライブを対象とする
	loop
	if drv < 1 {
		dialog "１つ以上のトラックが存在するドライブが見つかりませんでした"
		end
	}
	sdim track, drv / 100 * 3
	repeat drv / 100, 1
		if track ! "" : track += "\n"
		track += str(cnt)
	loop
	pos 10, 10 : combox index, 100, track
	pos 80, 10 : button gosub "回答", *answer
	mciload str(drv \ 100)
	mcisettime "tmsf"
	randomize
	r = rnd(drv / 100)
	mciplay str(r + 1), ""
	pos 10, 120 : mes "現在再生中のトラックはどれでしょう？"
	stop

*answer
	if index + 1 = mcitracknow() {
		dialog "ご名答！"
		end
	}
	mes str (index + 1) + "トラックではありません"
	return