[HSPBC] Tips

	～ネットワーク～

サーバーにファイルをアップロード (要WININET.DLL)

ＨＳＰ３からＨＳＰＩｎｅｔ．ＤＬＬが標準で同梱されており、
このＤＬＬの命令を使うことでインターネット上のデータを取り込むことが出来ます。
便利なものですが、作成した実行ファイルと共にＤＬＬを同梱する必要があるので、
様々な理由により「なんとかＤＬＬナシで実現できないか」と思う人たちの為の参考Ｔｉｐｓ。
ＨＳＰＩｎｅｔ．ＤＬＬは、Ｗｉｎｄｏｗｓ標準搭載のＷｉｎＩｎｅｔ．ＤＬＬのラッパーＤＬＬなので、
ＷｉｎＩｎｅｔ．ＤＬＬのＡＰＩ関数を直接呼び出すことで、
ＨＳＰＩｎｅｔ．ＤＬＬを同梱することなく実現させることが可能となります。

今回はＦＴＰサーバーのリソースとしてファイルをアップロードするftpput命令に取って代わる
ＷｉｎＩｎｅｔ．ＤＬＬのＡＰＩ関数FtpPutFileを使ったサンプルモジュールを紹介します。
ＡＰＩ関数FtpPutFileに指定するのは第１引数から順に、「セッションハンドル」「転送ファイル」
「作成リソース」「転送フラグ」「コールバック関数に渡すアプリケーション定義値」です。
セッションハンドルはサーバーと接続した際のログインセッションハンドルを、
転送ファイルはアップロード対象のファイル名(を格納した変数ポインタ)を、
作成リソースはアップロードしたリソースの保存ファイル名(を格納した変数のポインタ)を、
転送フラグは以下の転送方法を示す定義値を、

FTP_TRANSFER_TYPE_UNKNOWN 0x0000 デフォルトモード(バイナリー)で転送。
FTP_TRANSFER_TYPE_ASCIIINTERNET_FLAG_TRANSFER_ASCII 0x0001 テキストファイル用のアスキーモードで転送。
FTP_TRANSFER_TYPE_BINARYINTERNET_FLAG_TRANSFER_BINARY 0x0002 データそのままのバイナリーモードで転送。

コールバックする値は０を、それぞれ指定しましょう。

既に同名リソースが存在する場合は上書きされるので、
重要なリソースが誤って上書きされてしまわないように注意してください。
カレントディレクトリ以外にアップロードするには対象ディレクトリを変更する必要があります。
コチラを参考にしてカレントディレクトリを予め変更しておいてください。
尚、ＡＰＩ関数FtpPutFileの戻り値は成功した(＝１)か否(＝０)かを示す真偽値です。
この値を元に転送成功・失敗を判断すると良いでしょう。

inetinit

[パラメータなし] インターネットサービスを開始するだけである為、パラメータは必要ない。

inetend

[パラメータなし] インターネットハンドルを解放するだけの為、パラメータは必要ない。
尚、終了時に自動的に呼び出されるので命令を実行する必要はない。

inetlogin サーバー, ユーザー情報, サービス, ポート, オプション

サーバーホストサーバーアドレスまたはＩＰアドレス文字列を指定する。

ユーザー情報ログインユーザー名とパスワードをコロンで区切った形式で指定する。

サービス接続するサービス(１：ＦＴＰ２：Ｇｏｐｈｅｒ３：ＨＴＴＰ)を指定する。
尚、省略すればＦＴＰ接続を行う。

ポート使用するＴＣＰ／ＩＰポートを数値指定する。

オプションＦＴＰでパッシブモード利用する時、ＨＴＴＰでＨＴＴＰＳ通信する時は１を指定する。
それ以外の時は０または省略する。

inetlogout

[パラメータなし] サーバーとの接続を解除するだけの為、パラメータは必要ない。
尚、終了時に自動的に呼び出されるので命令を実行する必要はない。

ftpput 転送名, 保存名, 転送モード

転送名アップロードするファイルを指定する。尚、statには失敗(＝０)か成功(＝１)かのフラグが返る。

保存名保存するファイル名を指定する。

転送モード転送モード(０：バイナリー１：アスキー)を指定する。省略時はバイナリーモード。

	ll_libload wininet, "wininet.dll"
	ll_getproc InternetOpen, "InternetOpenA", wininet
	ll_getproc InternetCloseHandle, "InternetCloseHandle", wininet
	ll_getproc InternetConnect, "InternetConnectA", wininet
	ll_getproc FtpPutFile, "FtpPutFileA", wininet

#module
#deffunc inetinit
	mref stt, 64
	prm = 0, 0, 0, 0, 0
	agent = "hspbc"
	ll_getptr agent : ll_ret prm
	ll_callfunc prm, 5, InternetOpen@
	ll_ret hinet : stt = hinet
	return

#deffunc inetend onexit
	if hinet : ll_callfunc hinet, 1, InternetCloseHandle@
	return

#deffunc inetlogin str, str, int, int
	mref server, 32 : mref info, 33 : mref service, 2 : mref option, 3
	mref stt, 64
	instr i, info, ":"
	strlen i.1, info
	strmid user, info, , i
	strmid pass, info, i + 1, i.1 - i - 1
	if hinet = 0 : inetinit
	if user = "" : i.0 = 0 : else : ll_getptr user : ll_ret i.0
	if pass = "" : i.1 = 0 : else : ll_getptr pass : ll_ret i.1
	switch service
	case 2:  i.2 = 0x0002, 0 : swbreak
	case 3:  i.2 = 0x0003, 0 : swbreak
	default: i.2 = 0x0001, option ! 0 * 0x08000000
	swend
	ll_getptr server : ll_ret i.5
	prm = hinet, i.5, 0, i.0, i.1, i.2, i.3, 0
	ll_callfunc prm, 8, InternetConnect@
	ll_ret hsess : stt = hsess
	return

#deffunc inetlogout onexit
	if hsess : ll_callfunc hsess, 1, InternetCloseHandle@
	return	

#deffunc ftpput str, str, int
	mref putname, 32 : mref savename, 33 : mref mode, 2
	mref stt, 64
	prm = hsess, 0, 0, mode, 0
	ll_getptr putname : ll_ret prm.1
	ll_getptr savename : ll_ret prm.2
	ll_callfunc prm, 5, FtpPutFile@
	ll_ret prm : stt = prm
	return
#global

	sdim v, 128, 5
	pos  10,  10 : mes "ＦＴＰサーバー"
	pos 150,  10 : input v.0, 150, 22
	pos  10,  40 : mes "ユーザー名"
	pos 150,  40 : input v.1, 150, 22
	pos  10,  70 : mes "パスワード"
	pos 150,  70 : input v.2, 150, 22
	pos  10, 100 : mes "転送ファイル名"
	pos 150, 100 : input v.3, 250, 22
	pos 400, 100 : button "参照", *refer
	pos  10, 130 : mes "保存リソース名"
	pos 150, 130 : input v.4, 150, 22
	pos 150, 160 : button "転送", *connect
	stop

*refer
	dialog "", 16, "転送元ファイル"
	if stat {
		objprm 3, refstr
		getpath s, v.3, 8 // 配列(v.4)には格納できない(バグ？)
		objprm 5, s
	}
	stop

*connect
	inetlogin v, v.1 + ":" + v.2
	if stat {
		ftpput v.3, v.4
		if stat {
			dialog "転送しました"
		} else {
			dialog "接続には成功しましたがファイル転送に失敗しました"
		}
	} else {
		dialog "接続に失敗しました"
	}
	stop

inetinit

[パラメータなし] インターネットサービスを開始するだけである為、パラメータは必要ない。

inetlogin サーバー, ユーザー, パスワード, サービス, オプション

サーバーホストサーバーアドレスまたはＩＰアドレス文字列を指定する。

ユーザーログインユーザー名を指定する。

パスワードログインパスワードを指定する。

サービス接続するサービス(１：ＦＴＰ２：Ｇｏｐｈｅｒ３：ＨＴＴＰ)を指定する。
尚、省略すればＦＴＰ接続を行う。

オプションＦＴＰでパッシブモード利用する時、ＨＴＴＰでＨＴＴＰＳ通信する時は１を指定する。
それ以外の時は０または省略する。

#uselib "wininet.dll"
#cfunc	global InternetOpen "InternetOpenA" sptr, int, int, int, int
#func	global InternetCloseHandle "InternetCloseHandle" int
#cfunc	global InternetConnect "InternetConnectA" int, sptr, int, int, int, int, int, int
#cfunc	global FtpPutFile "FtpPutFileA" int, sptr, sptr, int, int

#module
#deffunc inetinit
	hinet = InternetOpen("hspbc")
	return hinet

#deffunc inetend onexit
	if hinet : InternetCloseHandle hinet
	return

#deffunc inetlogin str server, str user, str pass, int service, int option, local i, local s
	if hinet = 0 : inetinit
	s = user, pass
	if user = "" : i.0 = 0 : else : i.0 = varptr(s.0)
	if pass = "" : i.1 = 0 : else : i.1 = varptr(s.1)
	switch service
	case 2:  i.2 = 0x0002, 0 : swbreak
	case 3:  i.2 = 0x0003, 0 : swbreak
	default: i.2 = 0x0001, (option ! 0) * 0x08000000
	swend
	hsess = InternetConnect(hinet, server, , i.0, i.1, i.2, i.3)
	return hsess

#deffunc inetlogout onexit
	if hsess : InternetCloseHandle hsess
	return

#deffunc ftpput str putname, str savename, int mode
	return FtpPutFile(hsess, putname, savename, mode)
#global

	sdim v, 128, 5
	pos  10,  10 : mes "ＦＴＰサーバー"
	pos 150,  10 : input v.0, 150, 20
	pos  10,  40 : mes "ユーザー名"
	pos 150,  40 : input v.1, 150, 20
	pos  10,  70 : mes "パスワード"
	pos 150,  70 : input v.2, 150, 20
	pos  10, 100 : mes "転送ファイル名"
	pos 150, 100 : input v.3, 250, 20
	pos 400, 100 : button gosub "参照", *refer
	pos  10, 130 : mes "保存リソース名"
	pos 150, 130 : input v.4, 150, 20
	pos 150, 160 : button gosub "転送", *connect
	stop

*refer
	dialog "", 16, "転送元ファイル"
	if stat {
		objprm 3, refstr
		objprm 5, getpath(refstr, 8)
	}
	return

*connect
	inetlogin v, v.1, v.2
	if stat {
		ftpput v.3, v.4
		if stat {
			dialog "転送しました"
		} else {
			dialog "接続には成功しましたがファイル転送に失敗しました"
		}
	} else {
		dialog "接続に失敗しました"
	}
	return