ll_libload advapi, "advapi32.dll"
	ll_getproc RegOpenKeyEx, "RegOpenKeyExA", advapi
	ll_getproc RegQueryValueEx, "RegQueryValueExA", advapi
	ll_getproc RegCloseKey, "RegCloseKey", advapi

#module
#deffunc gethkey str
	mref string, 32
	sdim s, 22, 7
	mref stt, 64
	mref rstr, 65
	s.0 = "HKEY_CLASSES_ROOT", "HKEY_CURRENT_USER", "HKEY_LOCAL_MACHINE", "HKEY_USERS"
	s.4 = "HKEY_PERFORMANCE_DATA", "HKEY_CURRENT_CONFIG", "HKEY_DYN_DATA"
	strmid rstr, string, 0, 1
	if rstr ! "H" {
		i = 0 + rstr
		rstr = s.i
		return
	}
	instr i, string, "\\"
	if i ! -1 : strmid rstr, string, 0, i : else : rstr = string
	stt = 0
	repeat 7
		if s.cnt = rstr {
			stt = 0x80000000 + cnt
			instr i.0, string, "\\"
			strlen i.1, string
			strmid rstr, string, i + 1, i.1 - i.0 - 1
			break
		}
	loop
	return

#deffunc regopenkey val, str, int
	mref hkey, 16 : mref path, 33 : mref sa, 3
	mref stt, 64
	gethkey path
	if stat = 0 : return
	path = refstr
	prm = stat, 0, 0, (sa = 0) * 0x000F003F + sa
	ll_getptr path : ll_ret prm.1
	ll_getptr hkey : ll_ret prm.4
	ll_callfunc prm, 5, RegOpenKeyEx@
	ll_ret prm : stt = prm
	return

#deffunc reggetvalue val, str ,int, int
	mref data, 24 : mref name, 33 : mref hkey, 2 : mref type, 3
	mref stt, 64
	if RegQueryValueEx = 0 {
	}
	prm = hkey
	i.1 = 256
	ll_getptr name : ll_ret prm.1
	ll_getptr i    : ll_ret prm.3
	ll_getptr data : ll_ret prm.4
	ll_getptr i.1  : ll_ret prm.5
	ll_callfunc prm, 6, RegQueryValueEx@
	ll_ret prm : stt = prm
	if i >= 4 & (i <= 6) | (i = 11) | (type ! 0) : mref data, 16
	if type : data = i
	return

#deffunc regclose int
	mref hkey, 0
	ll_callfunc hkey, 1, RegCloseKey@
	return
#global

	sdim dat, 128
	sdim path, 128
	mes "＜ＨＴＭＬエディタ＞"
	gethkey "1" // HKEY_CURRENT_USER
	path = refstr + "\\Software\\Microsoft\\Internet Explorer\\Default HTML Editor"
	regopenkey key, path
	if stat = 0 : reggetvalue dat, "Description", key
	if stat ! 0 : dat = "Error"
	mes "・プログラム：" + dat
	regclose key
	gethkey "1" // HKEY_CURRENT_USER
	path = refstr + "\\Software\\Microsoft\\Internet Explorer\\Default HTML Editor\\shell\\edit\\command"
	regopenkey key, path
	if stat = 0 : reggetvalue dat, "", key
	if stat ! 0 : dat = "Error"
	mes "・コマンド：" + dat
	regclose key
	mes
	sdim program, 20, 5
	sdim keys, 16, 5
	program = "電子メール", "ニュースグループ", "インターネット電話", "カレンダー", "連絡先一覧"
	keys = "Mail", "News", "Internet Call", "Calendar", "Contacts"
	repeat 5
		mes "＜" + program.cnt + "＞"
		gethkey "2" // HKEY_LOCAL_MACHINE
		path = refstr + "\\SOFTWARE\\Clients\\" + keys.cnt
		regopenkey key, path
		if stat = 0 {
			reggetvalue dat, "", key
			path += "\\" + dat
			if stat = 0 : reggetvalue dat, "", key
		}
		if stat ! 0 : dat = "Error"
		mes "・プログラム：" + dat
		regclose key
		path += "\\shell\\open\\command"
		regopenkey key, path
		if stat = 0 : reggetvalue dat, "", key
		if stat ! 0 : dat = "Error"
		mes "・コマンド：" + dat
		regclose key
		mes
	loop
stop

#uselib "advapi32.dll"
#cfunc global RegOpenKeyEx "RegOpenKeyExA" int, sptr, int, int, var
#cfunc global RegQueryValueEx "RegQueryValueExA" int, sptr, int, var, var, var
#func  global regclose "RegCloseKey" int

#module
#defcfunc gethkey str string, local i, local s
	mref rstr, 65
	s.0 = "HKEY_CLASSES_ROOT", "HKEY_CURRENT_USER", "HKEY_LOCAL_MACHINE", "HKEY_USERS"
	s.4 = "HKEY_PERFORMANCE_DATA", "HKEY_CURRENT_CONFIG", "HKEY_DYN_DATA"
	rstr = string
	if strmid(rstr, 0, 1) ! "H" : return s(int(rstr))
	if instr(rstr, , "\\") ! -1 : rstr = strmid(rstr, 0, instr(rstr, , "\\"))
	foreach s
		if s.cnt = rstr {
			i = 0x80000000 + cnt
			rstr = string
			rstr = strmid(rstr, instr(rstr, , "\\") + 1, strlen(rstr) - instr(rstr, , "\\") - 1)
			break
		}
	loop
	return i

#defcfunc regopenkey var hkey, var path, int sa, local s
	return RegOpenKeyEx(int(gethkey(path)), refstr, , (sa = 0) * 0x000F003F + sa, hkey)

#defcfunc reggetvalue var data, int hkey, str name, int type, local i
	i = 256
	i.1 = RegQueryValueEx(hkey, name, , i.2, data, i)
	if type : data = i.2
	return i.1
#global

	sdim dat, 128
	sdim path, 128
	mes "＜ＨＴＭＬエディタ＞"
	path = gethkey("1") + "\\Software\\Microsoft\\Internet Explorer\\Default HTML Editor"
	if regopenkey(key, path) ! 0 | reggetvalue(dat, key, "Description") ! 0 : dat = "Error"
	mes "・プログラム：" + dat
	regclose key
	path += "\\shell\\edit\\command"
	if regopenkey(key, path) ! 0 | reggetvalue(dat, key, "") ! 0 : dat = "Error"
	mes "・コマンド：" + dat
	regclose key
	mes
	sdim program, 20, 5
	sdim keys, 16, 5
	program = "電子メール", "ニュースグループ", "インターネット電話", "カレンダー", "連絡先一覧"
	keys = "Mail", "News", "Internet Call", "Calendar", "Contacts"
	foreach keys
		mes "＜" + program.cnt + "＞"
		path = gethkey("2") + "\\SOFTWARE\\Clients\\" + keys.cnt
		dat = "Error"
		if regopenkey(key, path) = 0 & reggetvalue(dat, key, "") = 0 {
			path = gethkey("2") + "\\SOFTWARE\\Clients\\" + keys.cnt + "\\" + dat
			if regopenkey(key, path) ! 0 | reggetvalue(dat, key, "") ! 0 : dat = "Error"
		}
		mes "・プログラム：" + dat
		regclose key
		path += "\\shell\\open\\command"
		if regopenkey(key, path) ! 0 | reggetvalue(dat, key, "") ! 0 : dat = "Error"
		mes "・コマンド：" + dat
		regclose key
		mes
	loop