ll_libload advapi, "advapi32.dll"
	ll_getproc RegOpenKeyEx, "RegOpenKeyExA", advapi
	ll_getproc RegQueryValueEx, "RegQueryValueExA", advapi
	ll_getproc RegSetValueEx, "RegSetValueExA", advapi
	ll_getproc RegCloseKey, "RegCloseKey", advapi

#module
#deffunc gethkey str
	mref string, 32
	sdim s, 22, 7
	mref stt, 64
	mref rstr, 65
	s.0 = "HKEY_CLASSES_ROOT", "HKEY_CURRENT_USER", "HKEY_LOCAL_MACHINE", "HKEY_USERS"
	s.4 = "HKEY_PERFORMANCE_DATA", "HKEY_CURRENT_CONFIG", "HKEY_DYN_DATA"
	strmid rstr, string, 0, 1
	if rstr ! "H" {
		i = 0 + rstr
		rstr = s.i
		return
	}
	instr i, string, "\\"
	if i ! -1 : strmid rstr, string, 0, i : else : rstr = string
	stt = 0
	repeat 7
		if s.cnt = rstr {
			stt = 0x80000000 + cnt
			instr i.0, string, "\\"
			strlen i.1, string
			strmid rstr, string, i + 1, i.1 - i.0 - 1
			break
		}
	loop
	return

#deffunc regopenkey val, str, int
	mref hkey, 16 : mref path, 33 : mref sa, 3
	mref stt, 64
	gethkey path
	if stat = 0 : return
	path = refstr
	prm = stat, 0, 0, (sa = 0) * 0x000F003F + sa
	ll_getptr path : ll_ret prm.1
	ll_getptr hkey : ll_ret prm.4
	ll_callfunc prm, 5, RegOpenKeyEx@
	ll_ret prm : stt = prm
	return

#deffunc reggetvalue val, str ,int, int
	mref data, 24 : mref name, 33 : mref hkey, 2 : mref type, 3
	mref stt, 64
	prm = hkey
	i.1 = 256
	ll_getptr name : ll_ret prm.1
	ll_getptr i    : ll_ret prm.3
	ll_getptr data : ll_ret prm.4
	ll_getptr i.1  : ll_ret prm.5
	ll_callfunc prm, 6, RegQueryValueEx@
	ll_ret prm : stt = prm
	if i >= 4 & (i <= 6) | (i = 11) | (type ! 0) : mref data, 16
	if type : data = i
	return

#deffunc regsetnum str, int, int, int
	mref name, 32 : mref data, 1 : mref hkey, 2 : mref type, 3
	mref stt, 64
	if type = 3 {
		s = "" + data
		strlen i, s
	} else {
		if type = 11 : i = 8 : else : i = 4
	}
	prm = hkey, 0, 0, (type = 0) * 4 + type, 0, i
	ll_getptr name : ll_ret prm.1
	ll_getptr data : ll_ret prm.4
	ll_callfunc prm, 6, RegSetValueEx@
	ll_ret prm : stt = prm
	return

#deffunc regclose int
	mref hkey, 0
	ll_callfunc hkey, 1, RegCloseKey@
	return
#global

	sdim path, 128
	dat = 2		// 同時ＤＬ上限初期値
	gethkey "1"
	path = refstr + "\\Software\\Microsoft\\Windows\\CurrentVersion\\Internet Settings"
	regopenkey key, path
	if stat {
		dialog "[ " + path + " ]が存在しません", 1
		end
	}
	objsize 200, 25
	pos 10, 10 : button "ＨＴＴＰ１．１を優先", *priority
	pos 10, 40 : mes "同時ＤＬ上限数"
	pos 130, 40 : input dat, 20, 20, 2 
	pos 10, 70 : button "変更する", *change
	objsend 0, 0x00F4, 0x02, nouse // ボタンをチェックボックスに変更
	onexit *exit
	goto *priority

*load
	if http11 {
		reggetvalue dat, "MaxConnectionsPerServer", key
		if stat : reggetvalue dat, "MaxConnectionsPer1_0Server", key
	} else {
		reggetvalue dat, "MaxConnectionsPer1_0Server", key
		if stat : reggetvalue dat, "MaxConnectionsPerServer", key
	}
	objprm 1, dat
	return

*priority
	http11 = 1 - http11
	objsend 0, 0x00F1, http11, nouse
	gosub *load
	stop

*change
	int dat
	if dat < 1 {
		dialog "「1」以上の値を設定してください"
		gosub *load
	} else {
		dialog "同時ＤＬ上限数を「" + dat + "」に変更してよろしいですか？", 2
		if stat = 6 {
			if http11 {
				regsetnum "MaxConnectionsPerServer", dat, key, 4
			} else {
				regsetnum "MaxConnectionsPer1_0Server", dat, key, 4
			}
			dialog "変更完了"
		} else {
			gosub *load
		}
	}
	stop

*exit
	regclose key

#uselib "advapi32.dll"
#cfunc global RegOpenKeyEx "RegOpenKeyExA" int, sptr, int, int, var
#cfunc global RegQueryValueEx "RegQueryValueExA" int, sptr, int, var, var, var
#func  global RegSetValueEx "RegSetValueExA" int, sptr, int, int, var, int
#func  global regclose "RegCloseKey" int

#module
#defcfunc gethkey str string, local i, local s
	mref rstr, 65
	s.0 = "HKEY_CLASSES_ROOT", "HKEY_CURRENT_USER", "HKEY_LOCAL_MACHINE", "HKEY_USERS"
	s.4 = "HKEY_PERFORMANCE_DATA", "HKEY_CURRENT_CONFIG", "HKEY_DYN_DATA"
	rstr = string
	if strmid(rstr, 0, 1) ! "H" : return s(int(rstr))
	if instr(rstr, , "\\") ! -1 : rstr = strmid(rstr, 0, instr(rstr, , "\\"))
	foreach s
		if s.cnt = rstr {
			i = 0x80000000 + cnt
			rstr = string
			rstr = strmid(rstr, instr(rstr, , "\\") + 1, strlen(rstr) - instr(rstr, , "\\") - 1)
			break
		}
	loop
	return i

#defcfunc regopenkey var hkey, var path, int sa, local s
	return RegOpenKeyEx(int(gethkey(path)), refstr, , (sa = 0) * 0x000F003F + sa, hkey)

#defcfunc reggetvalue var data, int hkey, str name, int type, local i
	i = 256
	i.1 = RegQueryValueEx(hkey, name, , i.2, data, i)
	if type : data = i.2
	return i.1

#deffunc regsetvalue int hkey, str name, var data, int type, local i
	if type = 0 | type = 1 | type = 2 | type = 6 | type = 7 | type = 8 : data = str(data) : i = strlen(data) + 1
	if type = 4 | type = 5 : data = int(data) : i = 4
	if type = 3 : i = strlen(str(data))
	if type = 11 : i = 8
	RegSetValueEx hkey, name, , (type = 0) * 1 + type, data, i
	return
#global

	sdim path, 128
	dat = 2		// 同時ＤＬ上限初期値
	path = gethkey("1") + "\\Software\\Microsoft\\Windows\\CurrentVersion\\Internet Settings"
	if regopenkey(key, path) {
		dialog "[ " + path + " ]が存在しません", 1
		end
	}
	objsize 140, 20
	pos 10, 10 : button gosub "ＨＴＴＰ１．１を優先", *priority
	pos 10, 40 : mes "同時ＤＬ上限数"
	pos 130, 40 : input dat, 20, 20, 2 
	pos 10, 70 : button gosub "変更する", *change
	sendmsg objinfo(0, 2), 0x00F4, 0x02 // ＩＤ０のボタンをチェックボックスに変更
	onexit *exit
	gosub *priority
	stop

*load
	if http11 {
		if reggetvalue(dat, key, "MaxConnectionsPerServer") {
			if reggetvalue(dat, key, "MaxConnectionsPer1_0Server") { }
		}
	} else {
		if reggetvalue(dat, key, "MaxConnectionsPer1_0Server") {
			if reggetvalue(dat, key, "MaxConnectionsPerServer") { }
		}
	}
	objprm 1, dat
	return

*priority
	http11 = 1 - http11
	sendmsg objinfo(0, 2), 0x00F1, http11
	gosub *load
	return

*change
	dat = int(dat)
	if dat < 1 {
		dialog "「1」以上の値を設定してください"
		gosub *load
	} else {
		dialog "同時ＤＬ上限数を「" + dat + "」に変更してよろしいですか？", 2
		if stat = 6 {
			if http11 {
				regsetvalue key, "MaxConnectionsPerServer", dat, 4
			} else {
				regsetvalue key, "MaxConnectionsPer1_0Server", dat, 4
			}
			dialog "変更完了"
		} else {
			gosub *load
		}
	}
	return

*exit
	regclose key
	end