〜 オブジェクト 〜
リストボックスにアイテムを追加・挿入・削除 
リストボックスに新たな項目を追加・既存項目を削除する場合、
アイテムを変数で管理しているなら変数値を更新してobjprm命令を実行すれば実現できますが、
定数で管理している場合には、一筋縄には行きませんね。
このような場合は、オブジェクトにメッセージを送る方法でリストアイテムの追加削除を行いましょう。
ＨＳＰ２はobjsend命令、ＨＳＰ３からはsendmsg命令でオブジェクトにメッセージを送信できますので、
リストボックスの最後に新たに項目を追加したい場合は「LB_ADDSTRING(=0x0180)」を、


	ＨＳＰ２「objsend オブジェクトＩＤ, 0x0180, 不使用(=0), 追加文字列(変数), 0」
	ＨＳＰ３「sendmsg オブジェクトハンドル, 0x0180, 不使用(=0), 追加文字列(変数のポインタ)」


リストボックスの途中に新たに項目を挿入したい場合は「LB_INSERTSTRING(=0x0180)」を、


	ＨＳＰ２「objsend オブジェクトＩＤ, 0x0181, 挿入位置, 挿入文字列(変数), 0」
	ＨＳＰ３「sendmsg オブジェクトハンドル, 0x0181, 挿入位置, 挿入文字列(変数のポインタ)」


リストボックスの既存項目を削除したい場合は「LB_DELETESTRING(=0x0182)」を、


	ＨＳＰ２「objsend オブジェクトＩＤ, 0x0182, 削除位置, 不使用(=0), 0」
	ＨＳＰ３「sendmsg オブジェクトハンドル, 0x0182, 削除位置, 不使用(=0)」で簡単に実現できます。


挿入や削除は項目位置を指定する必要がありますが、
先頭項目の指定ではない場合、大抵は選択項目を対象項目とすることと思います。
ＨＳＰでは選択アイテムを変数で管理しているので対象変数からの取得で確認できますが、
モジュール内で確認する場合等の変数へ直接アクセスしたくない場合は「LB_GETCURSEL(=0x0188)」を、


	ＨＳＰ２「objsend オブジェクトＩＤ, 0x0188, 不使用(=0), 不使用変数(=0), 0」
	ＨＳＰ３「sendmsg オブジェクトハンドル, 0x0188, 不使用(=0), 不使用(=0)」


とすることで確認できます。

listbox_index オブジェクトＩＤ
オブジェクトＩＤ選択行を取得するリストボックスオブジェクトＩＤを指定する。

listbox_add オブジェクトＩＤ, 文字列
オブジェクトＩＤ追加するリストボックスオブジェクトＩＤを指定する。
文字列追加する文字列を指定する。

listbox_ins オブジェクトＩＤ, 文字列, 挿入行
オブジェクトＩＤ追加するリストボックスオブジェクトＩＤを指定する。
文字列追加する文字列を指定する。
挿入行０を基準とした挿入行位置を指定する。

listbox_del オブジェクトＩＤ, 削除行
オブジェクトＩＤ追加するリストボックスオブジェクトＩＤを指定する。
文字列追加する文字列を指定する。
削除行０を基準とした削除行位置を指定する。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

#module
#deffunc listbox_index int
	mref id, 0
	mref stt, 64
	objsend id, 0x188, 0, nonuse // リスト選択アイテムを取得
	return stat

#deffunc listbox_add int, str
	mref id, 0 : mref string, 33
	s = string
	objsend id, 0x180, 0, s // リストアイテムを追加
	return

#deffunc listbox_ins int, str, int
	mref id, 0 : mref string, 33 : mref no, 2
	s = string
	objsend id, 0x181, no, s // リストアイテムを挿入
	return

#deffunc listbox_del int, int
	mref id, 0 : mref no, 1
	objsend id, 0x182, no, nonuse // リストアイテムを削除
	return
#global

	objsize 150, 20
	pos 10, 10
	button "追加", *list
	button "挿入", *list
	button "削除", *list
	pos 10, 100 : listbox index.1, 200, "リスト既存1\nリスト既存2\nリスト既存3" // オブジェクトＩＤ：３
	stop

*list
	// 押されたボタンの処理を行う
	btnid = stat
	listbox_index 3 : no = stat
	switch btnid
		case 0: lst.0++ : listbox_add 3, "リスト追加" + lst.0 : swbreak
		case 1: lst.1++ : listbox_ins 3, "リスト挿入" + lst.1, no : swbreak
		case 2: listbox_del 3, no : swbreak
	swend
	stop

受取先 = listbox_index(オブジェクトＩＤ)
受取先取得した選択行の受取先を指定する。
オブジェクトＩＤ選択行を取得するリストボックスオブジェクトＩＤを指定する。

listbox_add オブジェクトＩＤ, 文字列
オブジェクトＩＤ追加するリストボックスオブジェクトＩＤを指定する。
文字列追加する文字列を指定する。

listbox_ins オブジェクトＩＤ, 挿入行, 文字列
オブジェクトＩＤ追加するリストボックスオブジェクトＩＤを指定する。
挿入行０を基準とした挿入行位置を指定する。
文字列追加する文字列を指定する。

listbox_del オブジェクトＩＤ, 削除行
オブジェクトＩＤ追加するリストボックスオブジェクトＩＤを指定する。
文字列追加する文字列を指定する。
削除行０を基準とした削除行位置を指定する。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

#module
#defcfunc listbox_index int id
	sendmsg objinfo(id, 2), 0x0188, 0, 0 // リスト選択アイテムを取得
	return stat

#deffunc listbox_add int id, str string
	s = string
	v objinfo(id, 2), 0x0180, 0, s // リストアイテムを追加
	return

#deffunc listbox_ins int id, int no, str string
	s = string
	sendmsg objinfo(id, 2), 0x0181, no, s // リストアイテムを挿入
	return

#deffunc listbox_del int id, int no
	sendmsg objinfo(id, 2), 0x0182, no, 0 // リストアイテムを削除
	return
#global

	objsize 150, 20
	pos 10, 10
	button gosub "追加", *list
	button gosub "挿入", *list
	button gosub "削除", *list
	pos 10, 100 : listbox index.1, 200, "リスト既存1\nリスト既存2\nリスト既存3" // オブジェクトＩＤ：３
	stop

*list
	// 押されたボタンの処理を行う
	switch stat
		case 0: lst.0++ : listbox_add 3, "リスト追加" + lst.0 : swbreak
		case 1: lst.1++ : listbox_ins 3, listbox_index(3), "リスト挿入" + lst.1 : swbreak
		case 2: listbox_del 3, listbox_index(3) : swbreak
	swend
	return