ll_libload advapi, "advapi32.dll"
	ll_getproc RegOpenKeyEx, "RegOpenKeyExA", advapi
	ll_getproc RegQueryValueEx, "RegQueryValueExA", advapi
	ll_getproc RegSetValueEx, "RegSetValueExA", advapi
	ll_getproc RegDeleteValue, "RegDeleteValueA", advapi
	ll_getproc RegCloseKey, "RegCloseKey", advapi

#module
#deffunc gethkey str
	mref string, 32
	sdim s, 22, 7
	mref stt, 64
	mref rstr, 65
	s.0 = "HKEY_CLASSES_ROOT", "HKEY_CURRENT_USER", "HKEY_LOCAL_MACHINE", "HKEY_USERS"
	s.4 = "HKEY_PERFORMANCE_DATA", "HKEY_CURRENT_CONFIG", "HKEY_DYN_DATA"
	strmid rstr, string, 0, 1
	if rstr ! "H" {
		i = 0 + rstr
		rstr = s.i
		return
	}
	instr i, string, "\\"
	if i ! -1 : strmid rstr, string, 0, i : else : rstr = string
	stt = 0
	repeat 7
		if s.cnt = rstr {
			stt = 0x80000000 + cnt
			instr i.0, string, "\\"
			strlen i.1, string
			strmid rstr, string, i + 1, i.1 - i.0 - 1
			break
		}
	loop
	return

#deffunc regopenkey val, str, int
	mref hkey, 16 : mref path, 33 : mref sa, 3
	mref stt, 64
	gethkey path
	if stat = 0 : return
	path = refstr
	prm = stat, 0, 0, (sa = 0) * 0x000F003F + sa
	ll_getptr path : ll_ret prm.1
	ll_getptr hkey : ll_ret prm.4
	ll_callfunc prm, 5, RegOpenKeyEx@
	ll_ret prm : stt = prm
	return

#deffunc reggetvalue val, str ,int, int
	mref data, 24 : mref name, 33 : mref hkey, 2 : mref type, 3
	mref stt, 64
	prm = hkey
	i.1 = 256
	ll_getptr name : ll_ret prm.1
	ll_getptr i    : ll_ret prm.3
	ll_getptr data : ll_ret prm.4
	ll_getptr i.1  : ll_ret prm.5
	ll_callfunc prm, 6, RegQueryValueEx@
	ll_ret prm : stt = prm
	if i >= 4 & (i <= 6) | (i = 11) | (type ! 0) : mref data, 16 // 強制的に数値型に変換
	if type : data = i
	return

#deffunc regsetstr str, str, int, int
	mref name, 32 : mref data, 33 : mref hkey, 2 : mref type, 3
	mref stt, 64
	strlen i, data
	if type ! 3 : i++
	prm = hkey, 0, 0, (type = 0) * 1 + type, 0, i
	ll_getptr name : ll_ret prm.1
	ll_getptr data : ll_ret prm.4
	ll_callfunc prm, 6, RegSetValueEx@
	ll_ret prm : stt = prm
	return

#deffunc regdelvalue int, str
	mref hkey, 0 : mref name, 33
	mref stt, 64
	prm = hkey
	ll_getptr name : ll_ret prm.1
	ll_callfunc prm, 2, RegDeleteValue@
	ll_ret prm : stt = prm
	return

#deffunc regclose int
	mref hkey, 0
	ll_callfunc hkey, 1, RegCloseKey@
	return
#global

	sdim dat, 16
	sdim value, 128
	sdim path, 128
	delnum = 3 // 削除する項目数
	kakucyoushi = "zip" // 削除する拡張子
	listvalue = "MRUList" // 削除項目リスト
	gethkey "1"
	path = refstr + "\\Software\\Microsoft\\Windows\\CurrentVersion\\Explorer\\ComDlg32\\OpenSaveMRU\\" + kakucyoushi
	regopenkey key, path
	if stat {
		dialog "[ " + path + " ]が存在しません", 1
	} else {
		mes "1.現在の履歴は[ファイル名(N):]のコンボボックス下矢印を押して確認してください"
		mes "2.[キャンセル]ボタンを押してください([開く]ボタンを押してもいいけど)"
		dialog kakucyoushi, 16
		gosub *deletevalues
		regclose key
	}
	end

*deletevalues
	reggetvalue dat, listvalue, key
	if stat {
		dialog "[ " + listvalue + " ]が存在しません", 1
	} else {
		strlen i, dat
		if i = 0 {
			dialog "[ " + path + " ]は全て削除されています"
		} else {
			mes "- - - - - - - - - -"
			repeat i
				strmid listname, dat, 0, 1
				reggetvalue value, listname, key
				if stat = 0 {
					regdelvalue key, listname // 項目を削除
					if stat = 0 {
						mes "[ " + value + " ]を削除しました"
					} else {
						mes "[ " + value + " ]の削除に失敗しました"
					}
				} else {
					mes "[ " + listname + " ]の値が存在しません"
				}
				strmid dat, dat, 1, i - 1
				if cnt + 1 >= delnum : break
			loop
			regsetstr listvalue, dat, key // 削除項目リストを更新
			dialog "上位" + delnum + "つの項目名と値のセットを削除しました"
		}
	}
	return

#uselib "advapi32.dll"
#cfunc global RegOpenKeyEx "RegOpenKeyExA" int, sptr, int, int, var
#cfunc global RegQueryValueEx "RegQueryValueExA" int, sptr, int, var, var, var
#func  global RegSetValueEx "RegSetValueExA" int, sptr, int, int, var, int
#func  global regdelvalue "RegDeleteValueA" int, sptr
#func  global regclose "RegCloseKey" int

#module
#defcfunc gethkey str string, local i, local s
	mref rstr, 65
	s.0 = "HKEY_CLASSES_ROOT", "HKEY_CURRENT_USER", "HKEY_LOCAL_MACHINE", "HKEY_USERS"
	s.4 = "HKEY_PERFORMANCE_DATA", "HKEY_CURRENT_CONFIG", "HKEY_DYN_DATA"
	rstr = string
	if strmid(rstr, 0, 1) ! "H" : return s(int(rstr))
	if instr(rstr, , "\\") ! -1 : rstr = strmid(rstr, 0, instr(rstr, , "\\"))
	foreach s
		if s.cnt = rstr {
			i = 0x80000000 + cnt
			rstr = string
			rstr = strmid(rstr, instr(rstr, , "\\") + 1, strlen(rstr) - instr(rstr, , "\\") - 1)
			break
		}
	loop
	return i

#defcfunc regopenkey var hkey, var path, int sa, local s
	return RegOpenKeyEx(int(gethkey(path)), refstr, , (sa = 0) * 0x000F003F + sa, hkey)

#defcfunc reggetvalue var data, int hkey, str name, int type, local i
	i = 256
	i.1 = RegQueryValueEx(hkey, name, , i.2, data, i)
	if type : data = i.2
	return i.1

#deffunc regsetvalue int hkey, str name, var data, int type, local i
	if type = 0 | type = 1 | type = 2 | type = 6 | type = 7 | type = 8 : data = str(data) : i = strlen(data) + 1
	if type = 4 | type = 5 : data = int(data) : i = 4
	if type = 3 : i = strlen(str(data))
	if type = 11 : i = 8
	RegSetValueEx hkey, name, , (type = 0) * 1 + type, data, i
	return
#global

	sdim dat, 16
	sdim value, 128
	delnum = 3 // 削除する項目数
	kakucyoushi = "*" // 削除する拡張子
	listvalue = "MRUList" // 削除項目リスト
	path = gethkey("1") + "\\Software\\Microsoft\\Windows\\CurrentVersion\\Explorer\\ComDlg32\\OpenSaveMRU\\" + kakucyoushi
	if regopenkey(key, path) {
		dialog "[ " + path + " ]が存在しません", 1
	} else {
		mes "1.現在の履歴は[ファイル名(N):]のコンボボックス下矢印を押して確認してください"
		mes "2.[キャンセル]ボタンを押してください([開く]ボタンを押してもいいけど)"
		dialog kakucyoushi, 16
		gosub *deletevalues
		regclose key
	}
	end

*deletevalues
	if reggetvalue(dat, key, listvalue) {
		dialog "[ " + listvalue + " ]が存在しません", 1
	} else {
		if strlen(dat) = 0 {
			dialog "[ " + path + " ]は全て削除されています"
		} else {
			mes "- - - - - - - - - -"
			repeat strlen(dat)
				if reggetvalue(value, key, strmid(dat, 0, 1)) = 0 {
					regdelvalue key, strmid(dat, 0, 1) // 項目を削除
					if stat = 0 {
						mes "[ " + value + " ]を削除しました"
					} else {
						mes "[ " + value + " ]の削除に失敗しました"
					}
				} else {
					mes "[ " + strmid(dat, cnt, 1) + " ]の値が存在しません"
				}
				dat = strmid(dat, 1, strlen(dat) - 1)
				if cnt + 1 >= delnum : break
			loop
			regsetvalue key, listvalue, dat // 削除項目リストを更新
			dialog "上位" + delnum + "つの項目名と値のセットを削除しました"
		}
	}
	return