～ テキスト ～
ＳＪＩＳをＥＵＣに変換 
ＨＳＰ標準で扱うＳｈｉｆｔ-ＪＩＳ(ＳＪＩＳ)コードを、ＥＵＣ(ＥＵＣ-ＪＰ)に変換します。
アルゴリズムの仕様により「纊褜鍈銈蓜俉炻昱棈鋹曻彅ⅰⅱⅲ￤」等の変換できない文字が存在します。
全ての文字を変換可能にする場合、規則にそぐわない文字は個別に変換するなどの対策を講じてください。
尚、下記サンプルモジュールは、バッファオーバーフロートラップを設けていませんので、
エラーを出さないためにも、設定先の変数サイズは大きく確保しておく必要があります。
ＥＵＣコードは、改行が１バイトで済みますが、半角カナは２バイトとなりますので、
設定先変数サイズは元の文字列変数サイズの２倍分にしておけばオーバーフローしません。
ＨＳＰ３からは、ＨＳＰの機能によりメモリの自動確保機能がありますが、
poke命令を用いて直接書き込んでいるため、バッファサイズの自動拡張は行いません。注意しましょう。

sjistojis 設定先変数, 変換元変数
設定先変数変換したＥＵＣコードテキストを格納する変数を指定する。
変換元変数ＥＵＣコードに変換するＳＪＩＳコードテキストを格納した変数を指定する。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

#module
#deffunc sjistoeuc val, val
	mref euc, 24 : mref sjis, 25
	strlen len, sjis
	i = 0
	repeat len
		peek code, sjis, cnt
		// CR + LF → LF
		if code = 13 : poke euc, i, 10 : i++ : continue cnt + 2
		// 2バイト・半角カナ文字
		if code > 128 {
			// 半角カナは2バイトにする
			if code > 176 & (code < 224) {
			  poke euc, i, 142
			  poke euc, i + 1, code
			  i++
			} else {
			  peek code.1, sjis, cnt + 1 // 2バイト文字の下位バイト取得
			  if code.1 < 159 {
			    if code.0 < 160 : poke euc, i, code.0 * 2 - 97 : else : poke euc, i, code.0 * 2 - 225
			    if code.1 > 127 : poke euc, i + 1, code.1 + 96 : else : poke euc, i + 1, code.1 + 97
			  } else {
			    if code < 160 : poke euc, i, code * 2 - 96 : else : poke euc, i, code * 2 - 224
			    poke euc, i + 1, code.1 + 2
			  }
			  i += 2
			  continue cnt + 2
			}
			// 1バイト文字
		} else {
			poke euc, i, code
		}
		i++
	loop
	return
#global

	sdim file, 256
	dialog "txt", 16, "変換したいS-JIS(ANSI)形式のファイル"
	if stat = 0 : end
	notesel buf
	noteload refstr
	strlen size, buf
	sdim buf2, size * 2 // EUC変換後のサイズを元の2倍分確保しておく
	sjistoeuc buf2, buf
	dialog "txt",17,"保存するEUC形式のファイル名"
	if stat {
		dialog "保存しました。\nＥＵＣコードを読めるエディタで確認してください。"
		notesel buf2
		notesave refstr
	}

sjistoeuc 設定先変数, 変換元変数
設定先変数変換したＥＵＣコードテキストを格納する変数を指定する。
変換元変数ＥＵＣコードに変換するＳＪＩＳコードテキストを格納した変数を指定する。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

#module
#deffunc sjistoeuc var euc, var sjis, local wbite, local i, local code
	repeat strlen(sjis)
			code = peek(sjis, cnt)
			// CR + LF → LF
			if code = 13 : poke euc, i, 10 : i++ : continue cnt + 2
			// 2バイト・半角カナ文字
			if code > 128 {
			  // 半角カナは2バイトにする
			  if code > 176 & code < 224 {
			    poke euc, i + 0, 142
			    poke euc, i + 1, code
			    i++
			  } else {
			    code.1 = peek(sjis, cnt + 1) // 2バイト文字の下位バイト取得
			    if code.1 < 159 {
			      if code.0 < 160 : poke euc, i, code.0 * 2 - 97 : else : poke euc, i, code.0 * 2 - 225
			      if code.1 > 127 : poke euc, i + 1, code.1 + 96 : else : poke euc, i + 1, code.1 + 97
			    } else {
			      if code.0 < 160 : poke euc, i, code * 2 - 96 : else : poke euc, i, code.0 * 2 - 224
			      poke euc, i + 1, code.1 + 2
			    }
			    i += 2
			    continue cnt + 2
			  }
			// 1バイト文字
			} else {
			  poke euc, i, code
			}
			i++
	loop
	return
#global

	sdim file, 256
	dialog "txt", 16, "変換したいS-JIS(ANSI)形式のファイル"
	if stat = 0 : end
	notesel buf
	noteload refstr
	sdim buf2, strlen(buf) * 2 // EUC変換後のサイズを元の2倍分確保しておく
	sjistoeuc buf2, buf
	dialog "txt",17,"保存するEUC形式のファイル名"
	if stat {
		dialog "保存しました。\nＥＵＣコードを読めるエディタで確認してください。"
		notesel buf2
		notesave refstr
	}
	end