〜 テキスト 〜
平仮名をカタカナに変換 
英数字同様、かなもある一定の規則に従ってアスキーコードが割り振られています。
ひらがなは２バイト文字であり、１バイト目は１３０固定、２バイト目が１５９から１ずつ増加。
全角かなも２バイト文字で、１バイト目は１３１固定、２バイト目が６４から同様に１ずつ増加します。


	

		

			
コード0123456789

			
15X・・・・・・・・・ぁ

			
16Xあぃいぅうぇえぉおか

			
17Xがきぎくぐけげこごさ

			
18Xざしじすずせぜそぞた

			
19Xだちぢっつづてでとど

			
20Xなにぬねのはばぱひび

			
21Xぴふぶぷへべぺほぼぽ

			
22Xまみむめもゃやゅゆょ

			
23Xよらりるれろゎわゐゑ

			
24Xをん・・・・・・・・

		

			
		

			
コード0123456789

			
 6X・・・・ァアィイゥウ

			
 7Xェエォオカガキギクグ

			
 8Xケゲコゴサザシジスズ

			
 9Xセゼソゾタダチヂッツ

			
10Xヅテデトドナニヌネノ

			
11Xハバパヒビピフブプヘ

			
12Xベペホボポマミ・ムメ

			
13Xモャヤュユョヨラリル

			
14Xレロヮワヰヱヲンヴヵ

			
15Xヶ・・・・・・・・・

		

			


全角カナの「ミ」と「ム」の間が開いていたり、「ン」の後に「ヴ」「ヵ」「ヶ」が存在したりするので、
ひらがなとカタカナは単純に文字コードをシフトするだけでは変換できません。
変換テーブルを用いるか、コード配置に沿うよう適時処理を分岐させて変換しましょう。
ＷｉｎＡＰＩには、形式を選択するだけで簡単に変換できるものが存在しますので、
コチラを利用するのも１つの手です。

hiratokata 対象変数
対象変数カタカナに変換する平仮名の含んだ文字列型変数を指定する。
尚、変換結果はシステム変数refstrに代入する為、４０９６バイトに収まる文字列にすること。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

#module
#deffunc hiratokata val
	mref string, 24
	mref rstr, 65
	repeat
		wpeek chk, string, cnt
		// 終了
		if chk = 0 : chk = cnt : break
		// 全角の場合
		if (chk & $FF > 128) & (chk & $FF < 160) | (chk & $FF > 223) {
			// ひらがなの場合
			if (chk & $FF = 130) & (chk >> 8 >= 159) & (chk >> 8 <= 241) {
			  // カタカナ１バイト目
			  chk++
			  // ひらがなとカタカナの差９５だけずらし、「ム」以降は１戻す
			  chk -= (95 - (chk >> 8 >= 222)) << 8
			}
			wpoke rstr, cnt, chk
			continue cnt + 2
		// 半角の場合
		} else {
			poke rstr, cnt, chk & $FF
		}
	loop
	poke rstr, chk // ゴミ表示を防ぐ
	return
#global

	sdim data, 128
	font "ＭＳ 明朝", 16
	data = "1２3４5あガさﾀﾞナパﾏヤらゎﾜゐヲゑﾝヴヵヶーｰＡbCｄEｆＧ"
	hiratokata data
	mes "元　　　" + data
	mes "片仮名　" + refstr
	stop

受取先 = hiratokata(対象変数)
受取先平仮名からカタカナに変換された文字列の受取先を指定する。
対象変数カタカナに変換する平仮名の含んだ文字列型変数を指定する。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

#module
#defcfunc hiratokata var string, local rstr, local chk
	sdim rstr, strlen(string) + 1
	repeat
		chk = wpeek(string, cnt)
		// 終了
		if chk = 0 : chk = cnt : break
		// 全角の場合
		if (chk & $FF) > 128 & (chk & $FF) < 160 | (chk & $FF) > 223 {
			// ひらがなの場合
			if (chk & $FF) = 130 & (chk >> 8) >= 159 & (chk >> 8) <= 241 {
			  // カタカナ１バイト目
			  chk++
			  // ひらがなとカタカナの差９５だけずらし、「ム」以降はさらに１ずらす
			  chk -= (95 - (chk >> 8 >= 222)) << 8
			}
			wpoke rstr, cnt, chk
			continue cnt + 2
		// 半角の場合
		} else {
			poke rstr, cnt, chk & $FF
		}
	loop
	return rstr
#global

	sdim data, 128
	font "ＭＳ 明朝", 16
	data = "1２3４5あガさﾀﾞナパﾏヤらゎﾜゐヲゑﾝヴヵヶーｰＡbCｄEｆＧ"
	mes "元　　　" + data
	mes "片仮名　" + hiratokata(data)