〜 テキスト 〜
全角カナを半角カナに変換 
英数字同様、かなもある一定の規則に従ってアスキーコードが割り振られています。
全角かなは２バイト文字で、１バイト目は１３１固定、２バイト目が６４から１ずつ増加し、
半角カナはコードの１６６から順に１ずつ増えていきます。


	

		

			
コード0123456789

			
 6X・・・・ァアィイゥウ

			
 7Xェエォオカガキギクグ

			
 8Xケゲコゴサザシジスズ

			
 9Xセゼソゾタダチヂッツ

			
10Xヅテデトドナニヌネノ

			
11Xハバパヒビピフブプヘ

			
12Xベペホボポマミ・ムメ

			
13Xモャヤュユョヨラリル

			
14Xレロヮワヰヱヲンヴヵ

			
15Xヶ・・・・・・・・・

		

			
		

			
コード0123456789

			
16X・・・・・・ヲァィゥ

			
17Xェォャュョッーアイウ

			
18Xエオカキクケコサシス

			
19Xセソタチツテトナニヌ

			
20Xネノハヒフヘホマミム

			
21Xメモヤユヨラリルレロ

			
22Xワン゛゜・・・・・・

		

	



半角カナの表は、文字化けを防ぐために全角で載せていますが、半角カナの並びと考えてください。
下記のスクリプトの半角カナを定義している箇所はそのまま半角で表示しているので、
作者の環境(ＩＥ)は問題ないものの、正常に表示されない環境も存在かもしれませんが了承願います。
上記の表を見ていただいたらわかる通り、「ヲ」の配置が全く違いますし、
濁点・半濁点だけ別に１バイトとなっており、「ヮ」「ヰ」「ヱ」「ヵ 」「ヶ」等も存在しません。
どちらも同じカタカナと言えど、全角と半角とで規則性が薄いということで、変換テーブルを用いてみました。
尚、一般的に使われる長音「ー」は全角カナのコード領域にはありませんでしたので、
長音の場合は、半角長音に置き換えるロジックを直接組み込んで対応しました。
コチラで紹介しているＷｉｎＡＰＩの利用でも、全角カナを半角カナに変換できますが、
半角にする際、カナ以外の全角英数も半角英数に変換してしまいます。
英数の半角全角はそのままで置いておきたいという場合は、下記を参考に自分で実装してしまいましょう。

hankanainit
[パラメータなし]初期化するだけのため、パラメータは必要ない。

hankana 対象変数
対象変数半角カナへの変換対象変数を指定する。
尚、変換結果はシステム変数refstrに代入する為、４０９６バイトに収まる文字列にすること。

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79

#module
#deffunc hankanainit
	// カタカナと同じ順序で半角カナを定義する
	sdim kana, 3, 87
	kana.0  = "ｧ" , "ｱ" , "ｨ" , "ｲ" , "ｩ"
	kana.5  = "ｳ" , "ｪ" , "ｴ" , "ｫ" , "ｵ"
	kana.10 = "ｶ" , "ｶﾞ", "ｷ" , "ｷﾞ", "ｸ"
	kana.15 = "ｸﾞ", "ｹ" , "ｹﾞ", "ｺ" , "ｺﾞ"
	kana.20 = "ｻ" , "ｻﾞ", "ｼ" , "ｼﾞ", "ｽ"
	kana.25 = "ｽﾞ", "ｾ" , "ｾﾞ", "ｿ" , "ｿﾞ"
	kana.30 = "ﾀ" , "ﾀﾞ", "ﾁ" , "ﾁﾞ", "ｯ"
	kana.35 = "ﾂ" , "ﾂﾞ", "ﾃ" , "ﾃﾞ", "ﾄ"
	kana.40 = "ﾄﾞ", "ﾅ" , "ﾆ" , "ﾇ" , "ﾈ"
	kana.45 = "ﾉ" , "ﾊ" , "ﾊﾞ", "ﾊﾟ", "ﾋ"
	kana.50 = "ﾋﾞ", "ﾋﾟ", "ﾌ" , "ﾌﾞ", "ﾌﾟ"
	kana.55 = "ﾍ" , "ﾍﾞ", "ﾍﾟ", "ﾎ" , "ﾎﾞ"
	kana.60 = "ﾎﾟ", "ﾏ" , "ﾐ" , " " , "ﾑ"
	kana.65 = "ﾒ" , "ﾓ" , "ｬ" , "ﾔ" , "ｭ"
	kana.70 = "ﾕ" , "ｮ" , "ﾖ" , "ﾗ" , "ﾘ"
	kana.75 = "ﾙ" , "ﾚ" , "ﾛ" , "ﾜ" , "ﾜ"
	kana.80 = "ｲ" , "ｴ" , "ｦ" , "ﾝ" , "ｳﾞ"
	kana.85 = "ｶ" , "ｹ"
	return

#deffunc hankana val
	mref string, 24
	mref rstr, 65
	p = 0
	repeat
		wpeek chk, string, cnt
		// 終了
		if chk = 0 : break
		// 全角の場合
		if (chk & $FF > 128) & (chk & $FF < 160) | (chk & $FF > 223) {
			// 全角カナの場合
			if (chk & $FF = 131) & (chk >> 8 >= 64) & (chk >> 8 <= 150) {
			  // 半角カナ取り出し
			  chk = (chk >> 8) - 64
			  wpeek chk, kana.chk
			  // 濁音・半濁音となる場合は2バイト分書き込む
			  if chk >> 8 = 'ﾞ' | (chk >> 8 = 'ﾟ') {
			    wpoke rstr, p, chk
			  } else {
			    poke rstr, p, chk & $FF
			    p-- // １バイトのための調整分
			  }
			// それ以外
			} else {
			  // 長音「ー」
			  if  chk = 23425 {
			    poke rstr, p, 'ｰ'
			    p-- // １バイトのための調整分
			  } else {
			    wpoke rstr, p, chk
			  }
			}
			p += 2
			continue cnt + 2
		}
		// 半角の場合
		poke rstr, p, chk & $FF
		p++
	loop
	poke rstr, p // EOF
	return
#global

	sdim data, 128
	data = "1２3４5あガさﾀﾞナパﾏヤらゎﾜゐヲゑﾝヴヵヶーｰＡbCｄEｆＧ"
	font "ＭＳ 明朝", 16
	mes "元の文字列　　" + data
	hankanainit                   // 初めに一度だけ実行する(半角カナを定義する)
	hankana data                  // 半角カナに変換する
	mes "半角カナ変換　" + refstr // 変換結果を表示する
	data = "イギシヂニピミヰ"
	mes "元の文字列　　" + data
	hankana data                  // 半角カナに変換する(hankanainitは実行不要)
	mes "半角カナ変換　" + refstr // 変換結果を表示する
	stop

hankanainit
[パラメータなし]初期化するだけのため、パラメータは必要ない。

結果 = hankana(対象変数)
結果変換した半角カナを含む文字列の受取先を指定する。
対象変数半角カナへの変換対象変数を指定する。 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

#module
#deffunc hankanainit
	// カタカナと同じ順序で半角カナを定義する
	sdim kana, 3, 87
	kana.0  = "ｧ" , "ｱ" , "ｨ" , "ｲ" , "ｩ"
	kana.5  = "ｳ" , "ｪ" , "ｴ" , "ｫ" , "ｵ"
	kana.10 = "ｶ" , "ｶﾞ", "ｷ" , "ｷﾞ", "ｸ"
	kana.15 = "ｸﾞ", "ｹ" , "ｹﾞ", "ｺ" , "ｺﾞ"
	kana.20 = "ｻ" , "ｻﾞ", "ｼ" , "ｼﾞ", "ｽ"
	kana.25 = "ｽﾞ", "ｾ" , "ｾﾞ", "ｿ" , "ｿﾞ"
	kana.30 = "ﾀ" , "ﾀﾞ", "ﾁ" , "ﾁﾞ", "ｯ"
	kana.35 = "ﾂ" , "ﾂﾞ", "ﾃ" , "ﾃﾞ", "ﾄ"
	kana.40 = "ﾄﾞ", "ﾅ" , "ﾆ" , "ﾇ" , "ﾈ"
	kana.45 = "ﾉ" , "ﾊ" , "ﾊﾞ", "ﾊﾟ", "ﾋ"
	kana.50 = "ﾋﾞ", "ﾋﾟ", "ﾌ" , "ﾌﾞ", "ﾌﾟ"
	kana.55 = "ﾍ" , "ﾍﾞ", "ﾍﾟ", "ﾎ" , "ﾎﾞ"
	kana.60 = "ﾎﾟ", "ﾏ" , "ﾐ" , " " , "ﾑ"
	kana.65 = "ﾒ" , "ﾓ" , "ｬ" , "ﾔ" , "ｭ"
	kana.70 = "ﾕ" , "ｮ" , "ﾖ" , "ﾗ" , "ﾘ"
	kana.75 = "ﾙ" , "ﾚ" , "ﾛ" , "ﾜ" , "ﾜ"
	kana.80 = "ｲ" , "ｴ" , "ｦ" , "ﾝ" , "ｳﾞ"
	kana.85 = "ｶ" , "ｹ"
	return

#defcfunc hankana var string, local rstr, local chk, local p
	sdim rstr, strlen(string) + 1
	repeat
		chk = wpeek(string, cnt)
		// 終了
		if chk = 0 : break
		// 全角の場合
		if (chk & $FF) > 128 & (chk & $FF) < 160 | (chk & $FF) > 223 {
			// 全角カナの場合
			if (chk & $FF) = 131 & (chk >> 8) >= 64 & (chk >> 8) <= 150 {
			  // 半角カナ取り出し
			  chk = (chk >> 8) - 64
			  chk = wpeek(kana.chk)
			  // 濁音・半濁音となる場合は2バイト分書き込む
			  if (chk >> 8) = 222 | (chk >> 8) = 223 {
			    wpoke rstr, p, chk
			  } else {
			    poke rstr, p, chk & $FF
			    p-- // １バイトのための調整分
			  }
			// それ以外
			} else {
			  // 長音「ー」
			  if chk = 23425 {
			    poke rstr, p, 'ｰ'
			    p-- // １バイトのための調整分
			  } else {
			    wpoke rstr, p, chk
			  }
			}
			p += 2
			continue cnt + 2
		}
		// 半角の場合
		poke rstr, p, chk & $FF
		p++
	loop
	return rstr
#global

	sdim data, 128
	data = "1２3４5あガさﾀﾞナパﾏヤらゎﾜゐヲゑﾝヴヵヶーｰＡbCｄEｆＧ"
	font "ＭＳ 明朝", 16
	mes "元の文字列　　" + data
	hankanainit                             // 初めに一度だけ実行する(半角カナを定義する)
	mes "半角カナ変換　" + hankana(data) // 半角カナに変換する
	data = "イギシヂニピミヰ"
	mes "元の文字列　　" + data
	mes "半角カナ変換　" + hankana(data) // 半角カナに変換する(hankanainitは実行不要)